committing changes in /etc after emerge run

Package changes:
+app-shells/tcsh-6.20.00

diff --git a/.etckeeper b/.etckeeper
index d2a0bfa9a10227262e02b0f14fbf9215bb6f4178..84ebf38449c8c5cccc1995a41f313fd956cc0592 100755 (executable)
--- a/.etckeeper
+++ b/.etckeeper
@@ -232,7 +232,9 @@ maybe chmod 0644 'cron.monthly/.keep_sys-process_cronbase-0'
 maybe chmod 0750 'cron.weekly'
 maybe chmod 0644 'cron.weekly/.keep_sys-process_cronbase-0'
 maybe chmod 0644 'crontab'
+maybe chmod 0644 'csh.cshrc'
 maybe chmod 0644 'csh.env'
+maybe chmod 0644 'csh.login'
 maybe chmod 0755 'dbus-1'
 maybe chmod 0644 'dbus-1/session.conf'
 maybe chmod 0755 'dbus-1/session.d'

diff --git a/csh.cshrc b/csh.cshrc
new file mode 100644 (file)
index 0000000..8e087a7
--- /dev/null
+++ b/csh.cshrc
@@ -0,0 +1,109 @@
+# /etc/csh.cshrc
+#
+# This file is sourced by all shells, login and non-login shells.
+# Some shells such as scp and rcp don't like any output, so make sure
+# this file doesn't display anything, or bad things will happen!
+#
+# Note that this is the first file the shell reads, hence for login
+# shells, the PATH is not yet set!
+
+
+# Set some variables for interactive shells
+if ( $?prompt ) then
+       # Find out if we should do colours
+       if ( -r "/etc/DIR_COLORS" ) then
+               if ( $?TERM ) then
+                       set colour = `"/bin/egrep" "^TERM ${TERM}"'$' "/etc/DIR_COLORS"`
+               endif
+       endif
+
+       # Set a Gentoo-ish prompt and setup colourful stuff if we have colour
+       set promptchars = "%#"
+       if ( $?colour ) then
+               if ( "$uid" == "0" ) then
+                       set prompt = "%{\033[0;1;34m%}(%{\033[0;1;31m%}%m%{\033[0m%}:%{\033[0;1;34m%}%c3%{\033[0;1;34m%}) %{\033[0;1;31m%}%#%{\033[0m%} "
+               else
+                       set prompt = "%{\033[0;1;34m%}(%{\033[0;1;32m%}%m%{\033[0m%}:%{\033[0;1;34m%}%c3%{\033[0;1;34m%}) %{\033[0;1;32m%}%n%{\033[0;1;32m%}%#%{\033[0m%} "
+               endif
+
+               # Enable colours for ls, etc.  Prefer ~/.dir_colors
+               if ( -f "${HOME}"/.dir_colors ) then
+                       eval `"/usr/bin/dircolors" -c "${HOME}"/.dir_colors`
+               else if ( -f "/etc/DIR_COLORS" ) then
+                       eval `"/usr/bin/dircolors" -c "/etc/DIR_COLORS"`
+               endif
+
+               alias ls 'ls --color=auto'
+               alias grep 'grep --color=auto'
+       else
+               if ( "$uid" == "0" ) then
+                       set prompt = "(%m:%c3) %# "
+               else
+                       set prompt = "(%m:%c3) %n%# "
+               endif
+       endif
+       unset colour
+
+       # Change the window title if appropriate
+       if ( $?TERM ) then
+               switch ( $TERM )
+                       case xterm*:
+                       case rxvt:
+                       case eterm:
+                       case Eterm:
+                       case screen:
+                       case vt100:
+                               if ( "$uid" == "0" ) then
+                                       set prompt = "%{\033]2;# %m:%~\007%}$prompt"
+                               else
+                                       set prompt = "%{\033]2;%m:%~\007%}$prompt"
+                               endif
+                       breaksw
+               endsw
+       endif
+
+       # Handle history
+       set history = 200
+       set histdup = erase
+
+       # Enable editing in EUC encoding for the languages where this make sense
+       if ( $?LANG ) then
+               switch ( ${LANG:r} )
+               case ja*:
+                       set dspmbyte=euc
+                       breaksw
+               case ko*:
+                       set dspmbyte=euc
+                       breaksw
+               case zh_TW*:
+                       set dspmbyte=big5
+                       breaksw
+               default:
+                       breaksw
+               endsw
+       endif
+
+       # One can use the "bindkey" facility to redefine the meaning of keys
+       # on the keyboard.  While you should set these preferences in your
+       # ~/.tcshrc, we include these bindings because many people expect
+       # them to be this way.
+
+       # INSERT    : toggles overwrite or insert mode.
+       bindkey    ^[[2~  overwrite-mode 
+       # DELETE    : delete char at cursor position.
+       bindkey    ^[[3~  delete-char
+       # HOME      : go to the beginning of the line.
+       bindkey    ^[[1~  beginning-of-line
+       # END       : go to the end of the line.
+       bindkey    ^[[4~  end-of-line
+       # PAGE UP   : search in history backwards for line beginning as current.
+       bindkey    ^[[5~  history-search-backward
+       # PAGE DOWN : search in history forwards for line beginning as current.
+       bindkey    ^[[6~  history-search-forward
+endif
+
+# Setup a default MAIL variable.  Note: on Interix, $USER can contain spaces
+if ( -f /var/mail/"$USER" ) then
+       setenv MAIL /var/mail/"$USER"
+       set mail = "$MAIL"
+endif

diff --git a/csh.login b/csh.login
new file mode 100644 (file)
index 0000000..7eb4a39
--- /dev/null
+++ b/csh.login
@@ -0,0 +1,73 @@
+# /etc/csh.login
+#
+# This file is sourced by all login shells only, after csh.cshrc has
+# been sourced!
+
+
+# Load environment settings from csh.env, which is created by
+# env-update from the files in /etc/env.d
+if ( -r "/etc/csh.env" ) then
+       source "/etc/csh.env"
+endif
+
+# 077 would be more secure, but 022 is generally quite realistic
+umask 022
+
+# Set up PATH depending on whether we're root or a normal user.
+# There's no real reason to exclude sbin paths from the normal user,
+# but it can make tab-completion easier when they aren't in the user's
+# PATH to pollute the executable namespace.
+#
+# It is intentional below to use setenv PATH instead of set -f path.
+# This way we can use the PATHs generated by portage.
+if ( "$uid" == "0" ) then
+       setenv PATH "/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin:${ROOTPATH}"
+else
+       setenv PATH "/usr/local/bin:/usr/bin:/bin:${PATH}"
+endif
+unsetenv ROOTPATH
+
+# Extract the value of EDITOR
+if ( ! $?EDITOR ) then
+       if ( -r "/etc/rc.conf" ) then
+               setenv EDITOR `egrep "^EDITOR=" "/etc/rc.conf" | sed -e 's/^.*="//' -e 's/"$//'`
+       endif
+       if ( ! $?EDITOR ) then
+               setenv EDITOR "/bin/nano"
+       endif
+endif
+
+# Default terminal initialization
+if ( -o /dev/$tty && ${?prompt} ) then
+       # Console
+       if ( ! ${?TERM} )           setenv TERM linux
+       if ( "$TERM" == "unknown" ) setenv TERM linux
+       if ( -x "/bin/stty" ) "/bin/stty" sane pass8 dec
+       unsetenv TERMCAP
+       settc km yes
+endif
+
+# Setup HOST and INPUTRC variables
+if ( ! $?HOST ) then
+       setenv HOST `hostname -s`
+endif
+if ( -r /etc/inputrc && ! $?INPUTRC ) then
+       setenv INPUTRC /etc/inputrc
+endif
+
+# If we're root, report who's logging in and out.
+if ( "$uid" == "0" ) then
+       set who = ( "%n has %a %l from %M." )
+       set watch = ( any any )
+endif
+
+# Source csh (environment) scripts from /etc/profile.d
+if ( -d "/etc/profile.d" ) then
+       set nonomatch
+       foreach i ( "/etc/profile.d/"*.csh )
+               if ( -r $i ) then
+                       source $i
+               endif
+       end
+       unset i nonomatch
+endif